autocrypt.el: Add MUA support for notmuch v3 PROPOSED

Sandra Snan: 1
 Add MUA support for notmuch

 3 files changed, 95 insertions(+), 0 deletions(-)

[PATCH autocrypt.el v3] Add MUA support for notmuch Export this patch

---
This works and is tested on Emacs 28. Only difference from V2 is the
derived-mode-p stuff in autocrypt.el. And I'm writing 100 times on the
blackboard tonight: "Test before send, not test after send".

 README.md            |  1 +
 autocrypt-notmuch.el | 93 ++++++++++++++++++++++++++++++++++++++++++++
 autocrypt.el         |  1 +
 3 files changed, 95 insertions(+)
 create mode 100644 autocrypt-notmuch.el

diff --git a/README.md b/README.md
index b1af7e6..b2fa3eb 100644
--- a/README.md
+++ b/README.md
@@ -10,6 +10,7 @@ Currently, it supports:
 - Rmail, as a viewer
 - Gnus, as a viewer
 - mu4e, as a viewer
+- notmuch, as a viewer
 - message, as a composer
 
 As of writing, this package doesn't fully implement the autocrypt
diff --git a/autocrypt-notmuch.el b/autocrypt-notmuch.el
new file mode 100644
index 0000000..54f47a2
--- /dev/null
+++ b/autocrypt-notmuch.el
@@ -0,0 +1,93 @@
+;; Copyright (C) 2020-2023  Free Software Foundation, Inc.
+
+;;; autocrypt-notmuch.el --- Autocrypt for notmuch -*- lexical-binding:nil -*-
+
+;; Author: Idiomdrottning <sandra.snan@idiomdrottning.org>
+
+;; This program is free software; you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation, either version 3 of the License, or
+;; (at your option) any later version.
+
+;; This program is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;; GNU General Public License for more details.
+
+;; You should have received a copy of the GNU General Public License
+;; along with this program.  If not, see <https://www.gnu.org/licenses/>.
+
+;;; Commentary:
+
+;; MUA specific functions for notmuch
+
+;; Setup example:
+
+;; (add-hook 'message-mode-hook #'autocrypt-mode)
+;; (add-hook 'notmuch-show-hook #'autocrypt-mode)
+;; (add-hook 'notmuch-search-hook #'autocrypt-mode)
+;; (add-hook 'notmuch-tree-hook #'autocrypt-mode)

Philip Kaludercic <philipk@posteo.net>

a month ago

There is no common hook?  Or do you think it is better to explicitly
mention each hook?

Next

+
+;;; Code:
+
+(require 'autocrypt)
+(require 'notmuch)
+
+(defvar autocrypt-notmuch-message-id nil
+  "Parameter to hold various message IDs for
+`autocrypt-process-header'. Requires dynamic binding, not

Philip Kaludercic <philipk@posteo.net>

a month ago

^
                               keep in mind to double-space
                               documentation!

Next

+lexical.")

Philip Kaludercic <philipk@posteo.net>

a month ago

The comment is not really necessary, since declaring dynamic binding is
the very point of using `defvar'.

Next

+
+(defun autocrypt-notmuch-search-rep-adv (&rest r)
+  (let* ((thread-id (notmuch-search-find-thread-id))
+         (autocrypt-notmuch-message-id
+          (with-temp-buffer ;; Temp buffers reduce flickering when
+                            ;; shelling out to the notmuch binary.

Philip Kaludercic <philipk@posteo.net>

a month ago

Interesting, do you know why this is?

Next

+            (plist-get
+             (plist-get (notmuch-call-notmuch-sexp "reply" "--format=sexp" thread-id) :original)
+             :id))))
+    (when autocrypt-notmuch-message-id
+      (autocrypt-process-header))))
+
+(defun autocrypt-notmuch-tree-rep-adv (&rest r)
+  (let ((autocrypt-notmuch-message-id (notmuch-tree-get-message-id)))
+    (autocrypt-process-header)))
+
+(defun autocrypt-notmuch-show-rep-adv (&rest r)
+  (let ((autocrypt-notmuch-message-id (notmuch-show-get-message-id)))
+    (autocrypt-process-header)))
+
+(defun autocrypt-notmuch-process-sexp-original (original)
+  (let ((autocrypt-notmuch-message-id (plist-get original :id)))
+    (autocrypt-process-header)))

Philip Kaludercic <philipk@posteo.net>

a month ago

This looks good!

Next

+
+;;;###autocrypt
+(defun autocrypt-notmuch--install ()
+  "Install autocrypt hooks for notmuch."
+  (if (boundp 'notmuch-mua-reply-functions)
+      (add-hook 'notmuch-mua-reply-functions #'autocrypt-notmuch-process-sexp-original)
+    (progn
+      (advice-add 'notmuch-search-reply-to-thread-sender :before #'autocrypt-notmuch-search-rep-adv)
+      (advice-add 'notmuch-tree-reply-sender :before #'autocrypt-notmuch-tree-rep-adv)
+      (advice-add 'notmuch-show-reply :before #'autocrypt-notmuch-show-rep-adv))))

Philip Kaludercic <philipk@posteo.net>

a month ago

A comment contextualising the difference between the two cases might be
appropriate.

Next

+
+(defun autocrypt-notmuch--uninstall ()
+  "Remove autocrypt hooks for notmuch."
+  (remove-hook 'notmuch-mua-reply-functions #'autocrypt-notmuch-process-sexp-original)
+  (advice-remove 'notmuch-search-reply-to-thread-sender #'autocrypt-notmuch-search-rep-adv)
+  (advice-remove 'notmuch-tree-reply-sender #'autocrypt-notmuch-tree-rep-adv)
+  (advice-remove 'notmuch-show-reply #'autocrypt-notmuch-show-rep-adv))
+
+(defun autocrypt-notmuch--get-header (header)
+  "Ask notmuch to return `header'."
+  (with-temp-buffer ;; Temp buffers reduce flickering when shelling
+                    ;; out to the notmuch binary.
+    (let ((coding-system-for-read 'no-conversion))
+      (call-process notmuch-command
+                    nil t nil "show" "--format=raw" "--body=false"
+                    autocrypt-notmuch-message-id))
+    (mail-fetch-field header)))
+
+(provide 'autocrypt-notmuch)
+
+;;; autocrypt-notmuch.el ends here
diff --git a/autocrypt.el b/autocrypt.el
index d03c86b..1c1b136 100644
--- a/autocrypt.el
+++ b/autocrypt.el
@@ -117,6 +117,7 @@ Every member of this list has to be an instance of the
 
 (defvar autocrypt-backends
   (list (lambda () (and (derived-mode-p 'mu4e-main-mode 'mu4e-view-mode) 'mu4e))
+        (lambda () (and (derived-mode-p 'notmuch-show-mode 'notmuch-search-mode 'notmuch-tree-mode) 'notmuch))

Philip Kaludercic <philipk@posteo.net>

a month ago

Note that this way of invoking `derived-mode-p' has been deprecated,
instead one should use

  (derived-mode-p '(notmuch-show-mode notmuch-search-mode notmuch-tree-mode))

Next

         (lambda () (and (derived-mode-p 'gnus-mode) 'gnus))
         (lambda () (and (derived-mode-p 'rmail-mode) 'rmail))
         (lambda () (and (derived-mode-p 'message-mode) 'message))

Philip Kaludercic <philipk@posteo.net>

a month ago

Sandra Snan <sandra.snan@idiomdrottning.org> writes:

-- 
2.39.2

Philip Kaludercic <philipk@posteo.net>

a month ago

First of all, sorry for the delay in responding to your message.  My
inbox has been overflowing for a while, and I am trying to remedy that.

Sandra Snan <sandra.snan@idiomdrottning.org> writes:

Philip Kaludercic <philipk@posteo.net>

a month ago

The spec[0] says

Philip Kaludercic <philipk@posteo.net>

a month ago

Or do you mean it would be better if autocrypt set the preference to
"manual" by default.

[0] https://docs.autocrypt.org/level1.html#accounts-controlled-by-the-mua

Philip Kaludercic <philipk@posteo.net>

a month ago

What package inserts the <#secure ...> tag?  If I know what it does,
I could try to improve the interaction.

Sandra Snan <sandra.snan@idiomdrottning.org> writes:

Philip Kaludercic <philipk@posteo.net>

a month ago

Do you know what public key was used to encrypt the message?  And are
you using the autocrypt-generated public key or your own?